_ForgeUser4858526 - SC2 Mapster Forums

Search results for '_ForgeUser4858526'

[Tutorial] Visual Studio .Net <How To Read SC2Lib file, XML> Nov 13, 2010

_ForgeUser4858526

Join Date: 8/15/2010
Posts: 34
Member Details

ReadIng XML Library [ SC2Lib ] Visual Studio Tutorial 2

This tutorial assums you know the basics from Tutorial 1.

http://forums.sc2mapster.com/resources/tutorials/14517-tutorial-creating-a-visual-studio-program-to-write/

This topic is for advance users, and many areas will not be explained. The Functioning code traverses a SC2Lib file created with SC2 map editor.

An SC2Lib file is essentialy a XML file. Using Visual studios System.Xml Imports lets us traverse the Structure of a SC2 Library.

This tutorial will be limited in only ready the file into Flat XML. The reconstruction of the library into a SC2 Map Editor view may be saved for Tutorial 3.

And now for the Show.

An SC2Lib file contains 6 major areas.

XML Opening Encoding, TriggerDATA, Root, Items, Elements, Element Value

Each of these areas are essentialy nested. The structure looks like what follows.

-XML Opening Encoding

TriggerDATA

Root

Item1

Item2

Item3

Element1

Element Value1

Element Value2

Element Value3

Element2

Element Value1

Element Value2

Element Value3

Element3

Element Value1

Element Value2

Element Value3

The root is everything contained within the main Library Folder inside the SC2 Map Editor. Following the root are nested elements.

To Traverse from opening the XML Document, we need to search Xelements, and Xelements Xelements. These Elements may contain Attributes, and if an Element does not contain Elements, then we search for Xnodes and its respective value must be used.

The Following is a logical traverse of a SC2Lib file.

Sub OpenXml()

    xmlDoc = XDocument.Load(XmlReader)

    For Each xE In xmlDoc.Elements

        xmlnode(xE)

    Next

End sub

-----------------------------------------

Sub xmlnode(ByRef xE As XElement)

    If Not xE.HasElements Then

        For Each xN In xE.Nodes

            xN.ToString, "Value"

        Next

    End If

    For Each xAtt In xE.Attributes

        xAtt.ToString, "Attribute"

    Next

    For Each xEnest In xE.Elements

        xmlnode(xEnest)

    Next

End Sub

By following this path, we visit all areas of a SC2Lib file. Now here is the results of looking at Built in Library.

The code for this project is commented below. There are a number of routines to help this be a fuctioning program.

-Form Loading

Prepare Image list for TreeView

Set set a status picture on the form to blank

-Resizing the form

Scale the TreeView based on the form size

-Load image list

Search for image files located in Icons folder.

Prepare treeview1

-Set TreeNode

Customize Settings

Return New TreeNode

-Add TreeNode to TreeView

Create Delegate to handle Cross Thread comunication with the Form Thread

Add TreeNode to TreeView

Do other Thread Operations

-Browse Button Clicked

Open XML File

-Traverse XML File

Create a New Thread to Compute XML File

Start Thread

Open XML File

Nested Loop Elements

Loop Nodes

Attributes

Elements

The following code is commented directly from the Project File.

Imports System.IO
Imports System.Xml
Imports System.Threading
Imports System.Drawing


Public Class frmSC2Lib_XML

    Dim xmlF As FileInfo 'xml file info
    Dim xmlDoc As New XDocument 'xml Document
    Dim ImgList As ImageList 'treeview image list
    Dim t1 As Thread 'Traverse Thread

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        LoadImageList() 'run sub Load treeview image collection

        Me.PictureBox1.Image = ImgList.Images("Blank") 'Form Status Image

    End Sub

    Sub LoadImageList() 'Load TreeView Icons (Every Gif, and BMP in folder Icons is loaded)

        ImgList = New ImageList

        ImgList.ImageSize = New Size(24, 24)

        Dim d As DirectoryInfo = New DirectoryInfo(Application.StartupPath & "\Icons")

        For Each f In d.GetFiles

            ImgList.Images.Add(f.Name.Replace(".bmp", "").Replace(".gif", ""), Image.FromFile(f.FullName))

        Next

        Me.TreeView1.ImageList = ImgList

    End Sub

    Private Sub Form1_Resize(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Resize

        Me.TreeView1.Size = New Size(Me.Width - (347 - 307), Me.Height - (474 - 383)) 'TreeView Resize

    End Sub

    Private Sub btnBrowse_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnBrowse.Click

        Dim dr As DialogResult = Me.OpenFileDialog1.ShowDialog 'Send Open File Dialog

        If dr = Windows.Forms.DialogResult.OK Then 'If file was selected

            Me.TreeView1.Nodes.Clear() 'Clear the TreeView

            xmlF = New FileInfo(OpenFileDialog1.FileName) 'Load the XML file info

            lblFileName.Text = xmlF.Name 'Change the form Label to match the file being opened

            TraverseXML() 'Start Travering the XML File

        End If

    End Sub

    Dim XMLImg As Image

    Sub TraverseXML() 'Starts a Thread for Traversing the XML file

        XMLImg = Image.FromFile(Application.StartupPath & "\Icons\Build.gif") 'get Animated Gif

        Me.PictureBox1.Image = XMLImg 'Form Status Image

        t1 = New Thread(AddressOf OpenXml) 'Create a Thread for opening xml

        t1.Start() 'Start OpenXml thread

    End Sub

    Sub OpenXml() 'Thread Sub

        Dim XmlReader As XmlReader = XmlReader.Create(xmlF.FullName) 'Create an XML Reader

        xmlDoc = XDocument.Load(XmlReader) 'Read the whole XML document

        Dim iNode As TreeNode = NodeSet(xmlF.Name, "XML") 'Create TreeNode for Document

        For Each xE In xmlDoc.Elements

            xmlnode(xE, iNode) 'Nested Loop Elements sending both element and parent TreeNode

        Next

        AddNodes(iNode) 'Send Parent Node to TreeView

    End Sub

    Public Delegate Sub AddNode(ByRef obj As Object) 'Delegate Instance on main Thread

    Sub AddNodes(ByRef obj As Object) 'Cross Thread activator, Add Main TreeNode to TreeView

        If Me.TreeView1.InvokeRequired Then 'Check for Cross Thread violation

            Dim ad As AddNode = New AddNode(AddressOf AddNodes) 'SetUp Delegate

            Me.TreeView1.Invoke(ad, obj) 'Invoke Thread on TreeView1 Thread

        Else 'Invoking on main Thread

            Me.PictureBox1.Image = ImgList.Images("Construct") 'Form Status Image

            Me.TreeView1.BeginUpdate() 'Ready the TreeView

            Me.TreeView1.Nodes.Add(obj) 'Add Parent Node to TreeView

            Me.TreeView1.EndUpdate() 'End Ready the TreeView

            Me.PictureBox1.Image = ImgList.Images("Built") 'Form Status Image

        End If

    End Sub

    Function NodeSet(ByRef Name As String, ByRef Type As String) As TreeNode 'Prepare TreeNode

        Dim TreeNode As TreeNode = New TreeNode(Name) 'Create a New TreeNode displaying text Name

        TreeNode.ImageKey = Type 'TreeNode Picture from Type
        TreeNode.SelectedImageKey = Type 'TreeNode Picture from Type

        Return TreeNode 'Return a prepared TreeNode

    End Function

    Sub xmlnode(ByRef xE As XElement, ByRef TreeNode As TreeNode)

        Dim iNode As TreeNode = NodeSet(xE.Name.ToString, "Element") 'Create TreeNode Element

        TreeNode.Nodes.Add(iNode) ' Add TreeNode Element to Parent TreeNode

        If Not xE.HasElements Then 'NLevel Element

            For Each xN In xE.Nodes 'Loop Nodes for Values

                iNode.Nodes.Add(NodeSet(xN.ToString, "Value")) 'Add TreeNode Value to TreeNode Element

            Next

        End If

        For Each xAtt In xE.Attributes 'Loop Attributes for Values

            iNode.Nodes.Add(NodeSet(xAtt.ToString, "Attribute")) 'Add TreeNode Attribute to TreeNode Element

        Next

        For Each xEnest In xE.Elements 'Loop Elements for all of the above

            xmlnode(xEnest, iNode) 'Nested Elements

        Next

    End Sub

End Class

And that’s how simple it is. Where it would get complicated is traversing from the Root location. I may save this for Tutorial 3 depending on community support.

Here is the asset when it is approved

http://www.sc2mapster.com/assets/reading-sc2lib-xml-tutorial-visu/

Happy Coding Sldprt (ItsAboutTime)

Last edited by _ForgeUser4858526: Nov 14, 2010

To post a comment, please login or register a new account.